智能合约开发及部署

更新时间：2020-11-07

IDE环境准备

本文采用Solidity语言开发以太坊智能合约。Solidity的开发环境我们直接使用超级链BaaS平台系统中提供的Remix web开发平台。因为超级链BaaS平台中提供的Remix IDE默认直接与目标以太坊网络相连，所以Remix IDE同时也可以作为部署、测试工具使用。

按照以下方法进入Remix IDE:

进入以太坊列表页，找到想要部署智能合约的目标以太坊网络，点击右侧的智能合约编辑器，系统会弹出新浏览器tab

在跳转前，会提示我们的账户密码，并在登录页中输入用户名和密码

等待Remix IDE页面加载完成，智能合约IDE主面板已经可以使用

在Run面板中确认已经连接目标以太坊的Web3 Provider

在Settings面板选择0.4.24版本的Solidity

在最左侧点击“+”，新建一个名为NoteWall.sol的智能合约

智能合约实现

编写智能合约的Solidity基础语法请读者自行阅读或参考完整源码。这里主要介绍便签板合约的主要实现。

便签对象的实现

便签板合约的实现关键就是定义一个便签在区块链上存储的数据格式。我们首先定义一个便签的结构体

struct Note {
	string title;
	string content;
	uint256 id;
}

便签由三部分构成，string类型的标题，string类型的便签正文以及一个256位的无符号整数类型表示的便签ID。

便签组的实现

接下来就是便签“对象”们如何组织化地保存下来，这里我们需要再定义一个mapping。

mapping(uint256 => Note) notes;

这个mapping管理着从ID到Note对象的索引。从用例来分析，便签板需要用到查找的场景主要有两处，一处是用户点击便签，编辑便签更新，另一处是用户查看所有的便签。由于Solidity中mapping不具有遍历性，所以我们需要再维护一个记录便签ID的数组，数组本身是可遍历的。

uint256[] noteIds;

新增便签的实现

新增一个便签除了需要新建一个Note对象，赋值title和content外，最主要的就是要为每一个Note对象分配一个不重复的ID。这里我们利用合约方法原子性的特点，通过维护一个累加的全局ID计数器来实现Note ID的唯一性。

具体原理就是当新建一个Note对象时，读取全局的ID计数器，将当前计数器值作为Note对象的ID，并将ID值++。

所以我们需要声明一个nextId，全局变量

uint256 nextId

接下来是新增便签的函数

/// Insert one new note object
function InsertNote(string _title, string _content) public {
    Note storage note = notes[nextId];
    noteIds.push(nextId);
    note.id = nextId;
    note.title = _title;
    note.content = _content;
    nextId = nextId + 1;
}

新增一个需要存储的Note对象，然后将nextId赋给note，并填入对应的标题和正文；此外将note索引到notes mapping中，插入新ID到noteIds数组中。

更新便签的实现

更新便签与新增便签稍有差别，需要从给定的Note ID中找到note对象再进行赋值。

function UpdateNote(uint256 _id, string _title, string _content) public {
    Note storage note = notes[_id];
    note.title = _title;
    note.content = _content;
}

获取所有的便签

按照用例3，用户应该会希望一次性获取所有的便签，但这在Solidity中无法通过一个方法就满足需求，原因是当前的solidity版本不支持方法返回一个struct或者struct的数组。所以我们拆分成两个函数来实现这个功能。第一个函数可以返回所有的便签ID，第二个函数则可以根据便签ID返回便签的标题和正文。

获取所有便签ID的函数：

/// Get all note ids
function GetNoteIds() public view returns(uint256[] _noteIds) {
    return noteIds;
}

读取便签标题和正文

/// Get one note object by its id
function GetNote(uint256 id) public view returns(string, string) {
    return (notes[id].title, notes[id].content);
}

这里我们使用了多值返回的特性。

所以最终获取所有的便签需要上层通过两步完成，首先调用GetNoteIds获取所有便签ID，之后再遍历便签ID，获取每个便签的标题和正文。虽然从传统软件设计看并不是最优的实现方式，但囿于EVM Solidity本身语法的局限性，智能合约的逻辑有时候需要做一些规避。

智能合约完整代码

pragma solidity ^0.4.0;
contract NoteWall {
    struct Note {
        string title;
        string content;
        uint256 id;
    }
    mapping(uint256 => Note) notes;
    uint256[] noteIds;
    uint256 nextId;

    /// Create a new ballot with $(_numProposals) different proposals.
    constructor() public {
        nextId = 0;
    }

    /// Get all note ids
    function GetNoteIds() public view returns(uint256[] _noteIds) {
        return noteIds;
    }
    
    /// Get one note object by its id
    function GetNote(uint256 id) public view returns(string, string) {
        return (notes[id].title, notes[id].content);
    }
    
    /// Insert one new note object
    function InsertNote(string _title, string _content) public {
        Note storage note = notes[nextId];
        noteIds.push(nextId);
        note.id = nextId;
        note.title = _title;
        note.content = _content;
        nextId = nextId + 1;
    }
    
    /// Update one note by its id
    function UpdateNote(uint256 _id, string _title, string _content) public {
        Note storage note = notes[_id];
        note.title = _title;
        note.content = _content;
    }
}

Remix IDE会自动保存合约文件

智能合约编译

在Remix中点击右侧的Compile面板

点击Start to compile进行编译，编译完成后如下图：

智能合约测试

Remix开发团队提供了Solidity的测试框架，可以开发完成简单的断言式单测。新建NoteWall_test.sol合约，此合约用来对NoteWall.sol做单测覆盖。 NoteWall_test.sol的内容如下：

pragma solidity ^0.4.7;
import "remix_tests.sol"; // this import is automatically injected by Remix.
import "./NoteWall.sol";

contract testNoteWall {
    NoteWall noteWallToTest;
    function beforeAll () {
       noteWallToTest = new NoteWall();
    }
    
    /// test InsertNote function
    function checkInsertNote () public {
        noteWallToTest.InsertNote("note title", "note content");
        var noteIds = noteWallToTest.GetNoteIds();
        var lastNoteId = noteIds[noteIds.length - 1];
        var (title, content) = noteWallToTest.GetNote(lastNoteId);
        Assert.equal(title, "note title", "note title should be the note compositions");
        Assert.equal(content, "note content", "note content should be the note compositions");
    }
    
    /// test UpdateNote function
    function checkUpdateNote () public {
        noteWallToTest.InsertNote("note title", "note content");
        var noteIds = noteWallToTest.GetNoteIds();
        var lastNoteId = noteIds[noteIds.length - 1];
        noteWallToTest.UpdateNote(lastNoteId, "new title", "new content");
        var (title, content) = noteWallToTest.GetNote(lastNoteId);
        Assert.equal(title, "new title", "new title should be the updated note compositions");
        Assert.equal(content, "new content", "new content should be the updated note compositions");
    }
    
    /// test GetNoteIds function
    function checkGetNoteIds () public {
        noteWallToTest.InsertNote("note title 0", "note content 0");
        noteWallToTest.InsertNote("note title 1", "note content 1");
        noteWallToTest.InsertNote("note title 2", "note content 2");
        var noteIds = noteWallToTest.GetNoteIds();
        Assert.equal(noteIds.length, 3, "noteIds' length should equal 3");
    }
    
    /// test GetNote function
    function checkGetNote () public {
        noteWallToTest.InsertNote("note title", "note content");
        var noteIds = noteWallToTest.GetNoteIds();
        var lastNoteId = noteIds[noteIds.length - 1];
        var (title, content) = noteWallToTest.GetNote(lastNoteId);
        Assert.equal(title, "note title", "note title should be the note compositions");
        Assert.equal(content, "note content", "note content should be the note compositions");
    }
}